Directorty Opus 5 - Magellan 2/Opus 5 - Magellan 2.iso/Extras/Install_3.3/Install deutsch

Text File | 1997-06-05 | 6KB | 145 lines

; $VER: Install.install deu 3.3 (05.06.97)

(set @default-dest "DOpus5:")
(set @language "deutsch")

(complete 0)

(set exec-version (/ (getversion) 65536))
(if (< exec-version 38)
 (abort "Dieses Programm benötigt mindestens OS 2.1.\n")
)

(message (cat "\nVersion Installation Programm\n"
              "für Directory Opus Magellan:\n\n"
              "geschrieben von Frédéric Steinfels\n"
              "[e-mail]\n\n"
              "Dieses Programm ist EMailWare.\n"
              "Bitte senden Sie mir ein EMail wenn Sie es benutzen!"
         )
)

(complete 6)

(set #updatefile "Erneuere die Datei")
(set #noupdatefile "Erneuere die Datei nicht")

(procedure Updatefile

(set #dest (askdir (prompt (cat "Wo ist oder wo wollen Sie " #file " installiert haben?"))
             (help "Wählen Sie die Schublade wo Sie die Datei installieren möchten. Verwenden Sie bitte den gegebenen/standard Pfad.")
                  (default (cat #dest))
         )
)

(set vernum1 (getversion (tackon #dest #file)) )
(set ver1 (/ vernum1 65536))
(set rev1 (- vernum1 (* ver1 65536) ) )


(set vernum2 (getversion (tackon #source #file)) )
(set ver2 (/ vernum2 65536))
(set rev2 (- vernum2 (* ver2 65536) ) )


(set #text  (cat "'" #file "'\n~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~\n"
                  "Version zur Zeit installiert   : " ver1 "." rev1 "\n\n"
                  "Version in diesem Archiv/Update: " ver2 "." rev2 "\n\n"
                  "Wollen Sie Version " ver2 "." rev2 " der Datei "
                  "'" #file "' vom Archiv/Update installieren?"
             )
)


(set pick (askchoice (choices #updatefile #noupdatefile) (prompt #text)    (help #text) (default pick)))

(if (= pick 0) (copyfiles (source (tackon #source #file )) (dest #dest))))

;end Procedure


(set upver
    (askchoice
        (prompt "Das Programm C:Version 40.1 (09.02.1993) enthält einen schwerwiegenden Fehler, der das ganze System zum Absturz bringen kann, wenn in den letzten vier Bytes einer datei ein $ Zeichen vorkommt. Die Wahrscheinlichkeit beträgt 1.6% für jede Datei. Es wird eine Sicherheitskopie mit dem Namen 'version.old' angelegt.\nDieser Patch wurde von Urs Eprecht erstellt.")
        (help "Ich empfehle Ihnen dringend, den Version Befehl von der Workbench 3.1 aufzutreiben, da der Patch nur mit dieser Version funktioniert. Leider weiss ich nicht, ob dieses Problem auch mit anderen OS Versionen auftritt. Bitte klicken Sie 'Fehler beseitigen' an.\nDa die Fehlerkorrektur einige Bytes benötigt, wurde der Text 'This disk requires Kickstart 2.04 or greater' auf 'OS 2.04 required' verkürzt.")
        (choices
            "Fehler beseitigen"
            "c:Version nicht verändern"
        )
    )
)

(if (= upver 0)
    (
        (rename "c:Version" "c:Version.old")
        (if
            (run ("c/spatch -oC:Version -pVersion/version.pch C:Version.old"))
            (
                (message "Leider war es nicht möglich, C:Version zu verändern. Entweder wurde er schon einmal verändert oder er liegt in einer anderen Version (nicht Workbench 3.1) vor.")
                (rename "c:Version.old" "c:Version")
            )
            (
                (message "C:Version erfolgreich erneuert!")
            )
        )
    )
)

(set #file "Install_Execute.dopus5")          (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 12)

(set #file "Install_GetID.dopus5")            (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 18)

(set #file "Install_Main.dopus5")             (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 25)

(set #file "Install_Preferences.dopus5")      (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 31)

(set #file "Install_Request.dopus5")          (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 37)

(set #file "Install_Scan.dopus5")             (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 43)

(set #file "Install_Startup.dopus5")          (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 50)

(set #file "Install.dopus5_ger.guide")        (set #source "")        (set #dest "DOpus5:Help")    (Updatefile)
(set #guide-dest #dest)
(complete 56)

(set #file "rexxdossupport.library")          (set #source "libs")    (set #dest "Libs:")          (Updatefile)
(complete 62)

(set #file "rexxtricks.library")              (set #source "libs")    (set #dest "Libs:")          (Updatefile)
(complete 68)

(set #file "Install_Locale.prefs")            (set #source "System")  (set #dest "DOpus5:System")  (Updatefile)
(complete 75)

(set #file "Install_Main.prefs")              (set #source "System")  (set #dest "DOpus5:System")  (Updatefile)
(complete 81)

(set #file "Install_Preferences_deutsch")     (set #source "Buttons") (set #dest "DOpus5:Buttons") (Updatefile)
(set #button-dest #dest)
(complete 87)

(set #file "Install.dopus5.catalog")          (set #source "Catalogs/deutsch") (set #dest "LOCALE:Catalogs/deutsch") (Updatefile)

(complete 93)

(rexx "ARexx/InstallerHelp.rexx" (tackon #button-dest "Install_Preferences_deutsch") "::" (tackon #guide-dest "Install.dopus5_ger.guide"))

(complete 100)

(message (cat "\nInstallation komplett\n\n"
              "Bitte lesen Sie die Anleitung (" (tackon #guide-dest "Install.dopus5_ger.guide") ") sorgfältig durch.\n"
              "Vergessen Sie nicht, dass Sie die Anleitung öffnen können, indem Sie mit der rechten Maustaste den Schalter 'zeige Einstellungen' links oben in der Knopfbank drücken.\n"
              "Entschuldigung für diese nicht so benutzerfreundliche Knopfbank. Eine richtige grafische Benutzeroberfläche hätte viel Speicher verschwendet.\n"
              "\n"
              "Viel Spass und vergessen Sie nicht, mir ein EMail zu schicken!\n"
         (all))
)
(exit (quiet))